MPC Transcriber and Timer (会話分析等文字化支援ソフト)

*倉庫では作成したソフトなどを紹介します.

MPC Transcriber and Timer(MTT)は,VLC Transcriber and Timer(VTT)の姉妹ソフトです.

VTTがVLCを再生ソフトに使うのに対し,MTTは,MPCを再生ソフトとして使用します.

現在デバグ中です.

僕はどちらかというと,軽量かつバグが少ないMPC派でしたが,うまくMPCにつなぐことができませんでした.
今回,いくつかの勉強をして,MPCを利用することができるようになりました.

(追記:HPCでは,再生速度を遅くすると,音声が低くなることを回避できないようです.音声が重要である場合は,VTTの使用をお勧めします.)

基本的な機能は変わりますせんので,詳細はVTTのページをご覧ください.

一点だけ.

tweaks

MPCのオプションから,Tweaksを選択し,真ん中のボックスにミリセカンドで巻き戻しの秒数を設定できます.おそらく最初は5000になっていると思いますが,3000ぐらいがおすすめです.

以下,DL用のリンクと,ソースコードです.再配布等,出典を明記していただれば可能です.もしもっといいものができた場合は,@neo_kixにご一報ください.

[日本語版·高解像度用・安定版]

https://dl.dropboxusercontent.com/u/85699252/MPC%20transcriber%20and%20timer%20neokix%2020170121.exe

※ファイルはVirustotalにてスキャンされ,有害でないとの報告があります.

https://www.virustotal.com/ja/file/cbf54761dece71dfab6bf8d799769010a6f0446248ceeb7a69b5ea7f7b7c6ba5/analysis/1485092495/

/*
 MPC Transcriber and timer neokix 20170121

All thanks to kojimu(http://d.hatena.ne.jp/kojimu/20110425/1303762269) and Cruncher1(https://autohotkey.com/board/topic/97904-simple-millisecond-timer-stopwatch/) for those base codes!
 Also, thanks to this superb icon by ava1219 (http://www.iconarchive.com/show/littlear-icons-by-ava1219/folder-document-icon.html)

Reminder
 Window Key-> #
 Ctrl Key -> ^
 Alt Key -> !

;ahk_class MediaPlayerClassicW

*/

#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
 #Warn ; Enable warnings to assist with detecting common errors.
 SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
 SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.

;; Millisecond Timer

AdjTime = 0

;Timer GUI
 Gui , Timer:Font , s8, Segoe UI
 Gui , Timer:Add , Text, x10 y10, MPC Transcriber and Timer
 Gui , Timer:Font , s25, Segoe UI
 Gui , Timer:Add , Text , Center w350 , 00:00:00:000
 Gui , Timer:Font , s10, Segoe UI
 Gui , Timer:Add , Button , x20 y100 w100 gStop Section , Stop
 Gui , Timer:Add , Button , x20 y100 w100 gStart , Start
 Gui , Timer:Add , Button , w70 ys gCopy, Copy
 Gui , Timer:Add , Button , w70 ys gReset , Reset
 Gui , Timer:Add , Button , w70 ys gHelp , Help
 Gui , Timer:Add , Button , x320 y7 w50 gExit , Exit
 Gui , Timer:+AlwaysOnTop
 Gui , Timer:Color, White
 Gui , Timer:Show , x1530 y700, Timer
 Control , Hide , , Buttn1 , Timer

;; This program needs MPC so let's make it happen
 IfWinExist ahk_class MediaPlayerClassicW
 Return

Else
 {
 Sleep, 200
 Run , C:\Program Files\MPC-HC\mpc-hc64.exe
 Return
 }

Exit

; Hotkeys
 #IfWinExist Timer
 F1::
 SetTitleMatchMode, 2
 GoSub, Start
 return

#IfWinExist Timer
 F12::
 SetTitleMatchMode, 2
 GoSub, Stop
 return

Start:
 Control , Hide , , Button2 , Timer
 Control , Show , , Button1 , Timer
 GuiControl , Focus , Button1
 StopClock = 0
 ControlGetText , DisplayTime , Static2
 ST := A_TickCount ; Start Time
 While StopClock = 0
 ControlSetText , Static2 , % FormatCT((A_TickCount - ST) + AdjTime)
 StopClock = 0
 Exit

Stop:
 Reset:
 Control , Show , , Button2 , Timer
 Control , Hide , , Button1 , Timer
 GuiControl , Focus , Button2
 StopClock = 1
 IF (A_ThisLabel = "Reset")
 {
 AdjTime = 0
 ControlSetText , Button2 , Start
 ControlSetText , Static2 , 00:00:00:000
 }else{
 AdjTime := 0
 ControlSetText , Button2 , Restart
 }

Exit

Copy:
 ControlGetText , Clipboard , Static2
 MsgBox, 262192, Time Copied to Clipboard, Copied to Clipboard: %Clipboard%, 2
 Exit

Help:
 msgbox, "このプログラムの終了は[X]ではなく[Exit]を利用してください `n `n <押し間違え防止のために以下のキーが変更されています> `n Ins→Backspace `n NumpadIns→Right `n Printscreen→Volume_Down `n Pause→Volume_Up `n カナkey → 全角/半角key `n 変換key → F7 `n `n<MPCプレイヤーの操作:キーボードから行えます> `n Ctrl+Up→Play&Pause `n Crtl+. → Speed up `n Ctrl+, → Speed down `n 無変換key/Home/左Alt→3秒戻し `n Ctrl+Right→3秒進む `n Shift+F1/F12→前/次のフレーム `n `n <タイマー操作> `n F1→開始 `n F12→終了 `n `n Thanks to kojimu(http://d.hatena.ne.jp/kojimu/20110425/1303762269) and Cruncher1(https://autohotkey.com/board/topic/97904-simple-millisecond-timer-stopwatch/) for base codes!`n Also, thanks to this superb icon by ava1219 (http://www.iconarchive.com/show/littlear-icons-by-ava1219/folder-document-icon.html) "
 return

Exit:
 ExitApp

TimerGuiClose:
 Winminimize

FormatCT(ms) ; Formats milliseconds into 00:00:00:000 (last three digits are milliseconds)
 {
 StringRight , mil , ms , 3
 StringTrimRight , sec , ms , 3
 min := Floor(sec/60)
 sec := sec-(min*60)
 hrs := Floor(min/60)
 min := min-(hrs*60)
 While StrLen(sec) <> 2
 sec := "0" . sec
 While StrLen(mil) <> 3
 mil := "0" . mil
 While StrLen(min) <> 2
 min := "0" . min
 While StrLen(hrs) <> 2
 hrs := "0" . hrs
 return , hrs . ":" . min . ":" . sec . ":" . mil
 }
 ;;;;;;

; Making keybord better
 ; Insert to Backspace
 Ins::
 Send, {BS}
 Return

; NumpadIns to Right
 NumpadIns::
 Send, {Right}
 Return

; Volume down
 Printscreen::
 Send, {Volume_Down}
 Return

; Volume up
 Pause::
 Send, {Volume_Up}
 Return

; カナkey to 全角/半角key
 vkF2sc070::
 Send, {vkF3sc029}
 Return

; 変換key to F7
 vk1Csc079::
 Send, {F7}
 Return

; MPC Player Control
 ; Play and Pause
 ^Up::
 SetTitleMatchMode, 2
 ControlSend, , {space}, ahk_class MediaPlayerClassicW
 Return

; Speeding up (0.10x)
 ^.::
 SetTitleMatchMode, 2
 ControlSend, , ^{Up}, ahk_class MediaPlayerClassicW
 Return

; Slowing down (0.10x)
 ^,::
 SetTitleMatchMode, 2
 ControlSend, , ^{Down}, ahk_class MediaPlayerClassicW
 Return

; 3seconds back using Left Alt key
 LAlt::
 SetTitleMatchMode, 2
 ControlSend, , {Left}, ahk_class MediaPlayerClassicW
 Return

; 3seconds back using 無変換key
 vk1Dsc07B::
 SetTitleMatchMode, 2
 ControlSend, , {Left}, ahk_class MediaPlayerClassicW
 Return

; 3 seconds back using Home key
 Home::
 SetTitleMatchMode, 2
 ControlSend, , {Left}, ahk_class MediaPlayerClassicW
 Return

; 3 seconds ahead
 ^Right::
 SetTitleMatchMode, 2
 ControlSend, , {Right}, ahk_class MediaPlayerClassicW
 Return

; next frame
 +F12::
 SetTitleMatchMode, 2
 ControlSend, , ^{Right}, ahk_class MediaPlayerClassicW

; next frame
 +F1::
 SetTitleMatchMode, 2
 ControlSend, , ^{Left}, ahk_class MediaPlayerClassicW

Return
広告