AutoHotkey 番外編 お助けミニスクリプト編

AutoHotkeyを使っていると，いろいろな細かいスクリプトを作る機会に恵まれます．ここでは，覚書として，役に立ちそうなスクリプトをいくつか公開します．どれも単純なものばかりなのですが，役に立つと思います．ヘルプなどを参考に，改造して使ってみてください．AutoHotkeyを少し勉強したことある人向けです．(追加:20170607)

瞬間日時挿入

;20170607_13:00　式に日時を挿入．形式をいじる場合はyyyyから始まる部分をいじる．
!D::
SetKeyDelay, -5
timeanddate := A_Now
FormatTime, timeanddate, , yyyyMMdd_HH:mm
Send, %timeanddate%
return

NumLockをいつでもONに

;Default state of lock keys
NumLock::
ScrollLock::
 SetNumlockState, AlwaysOn
 SetCapsLockState, AlwaysOff
 SetScrollLockState, AlwaysOff
Return

Wordでシフトを押しながらスクロールするとたくさんスクロール

;FastScroll
#IfWinActive, ahk_class OpusApp
+WheelDown::
Send, {WheelDown 10}
return

+WheelUp::
Send, {WheelUp 10}
return
#IfWinActive,

Appsキーを使ってActiveを表示

;Appskey -> Win+Tab
AppsKey::
If (A_PriorKey = "AppsKey")
	{
	Send, {Right}
	}
else
	{
	Send, #{Tab}
	}
return

スリープ状態にする

!^+s::
	DllCall("PowrProf\SetSuspendState", "int", 0, "int", 0, "int", 0)
Return

二種類のスピーカーを切り替える

;Switch Two Speaker Output
speaker := 0
#F6::
speaker := !speaker
Run, mmsys.cpl
WinWait, ahk_class #32770
If speaker
{
Send, {Down} 
}
else
{
Send, {Down 2} 
}
sleep,200
ControlClick, 既定値に設定(&S)
sleep,200
ControlClick, OK 
return

パワポ使用中に，MSペイントを使って画像の白黒を反転させる

^+H::
	send, ^c
IfWinNotExist, ahk_class MSPaintApp
	{
		run, mspaint.exe
		sleep, 200
		WinMaximize, ahk_class MSPaintApp
	}
	else
	{
		WinActivate, ahk_class MSPaintApp
		sleep, 200
		WinMaximize, A
	}
	send, ^v
	sleep, 200
	MouseClick, Right
	sleep, 200
	Send, E
	sleep, 200
	MouseClick, Left
	sleep, 200
	Send, ^c
	sleep, 200
	WinActivate, ahk_class PPTFrameClass
	sleep, 200
	send, ^v
return

選択した文字列をtextファイルに書き込む

Copipaster ver. 3.0
^+c::
tooltip, Copying...
SetTitleMatchMode, 2
IfWinExist, Appendtext
	{
	Gosub, askchromeactive
	}
	else
	{
	Gosub, askchromeactive
	Run,  XXXXXX ;(textファイルの絶対パスをここに)
	}
tooltip,
return

askchromeactive:
	FormatTime, clippedtime , , yyyy / MM / dd (dddd) hh:mm:ss
	SetKeyDelay, 5
	clipboard =
	wintitle =
	copycontents =
	url =
	sleep, 100
	Send, ^c										;コピー
	ClipWait, 5
	copycontents := clipboard
	WinGetTitle, wintitle, A	;Windowのタイトルを取得する
	IfWinActive, ahk_class Chrome_WidgetWin_1
		{
		clipboard =
		Send, ^l										;Ctrl+Lで，URLのバーへ移動
		sleep, 300
		Send, ^c
		ClipWait, 5
		url := clipboard
		FileAppend, %copycontents% `n %wintitle%:%url%`n貼り付け日時:%clippedtime%`n -------------------------------`n`n, XXXXXXXX ;(テキストの絶対アドレスをここに)
		} 
	else							;もしくは，(つまり，あれば)
		{
		FileAppend, %copycontents% `n `nファイル名:%wintitle% `n貼り付け日時:%clippedtime% `n ------------------------------- `n`n, XXXXXXXX ;(テキストの絶対アドレスをここに)
		}
	return